10 REM (null)TRESS (null)EST BY MID$OHN PEEKELTRAMI
20 REM (null)RANSLATED FOR THE LENOMMODORE 64 BY STR$ONNA (null). (null)OODY
30 POKE53281,7:REM SETS BACKGROUND COLOR TO LIGHT GREEN
40 POKE53280,5:REM SETS BORDER COLOR TO GRAY 1
50 PRINTCHR$(149):REM SETS CHARACTER COLOR TO GRAY 1
60 POKE53272,23:REM SELECTS UPPER/LOWER CASE
70 PRINTCHR$(8):REM DISABLES C/SHIFT KEY
80 :
90 REM READ DATA FROM DATA STATEMENTS
100 :
110 DIM T$(42),T(42)
120 FORI=1TO42
130 READT$(I),T(I)
140 NEXTI:GOTO220
150 :
160 REM HEADING SUBROUTINE
170 :
180 PRINTCHR$(147):PRINTCHR$(144):PRINTTAB(14)"[211][212][210][197][211][211][160][212][197][211][212]":PRINT:PRINT:PRINTCHR$(149):RETURN
190 :
200 REM GOTO TITLE PAGE
210 :
220 GOSUB1050
230 :
240 REM MAIN PROGRAM SECTION
250 :
260 REM S=12::::CHRISTMAS FACTOR
270 GOSUB180
280 GOSUB1170:REM INSTRUCTIONS
290 FORI=1TO42
300 GOSUB480
310 NEXTI
320 :
330 :REM PRINT RESULTS OF TEST
340 :
350 GOSUB180
360 PRINT"[217]OUR STRESS SCORE IS: ";S
370 IFS>300THENGOSUB750:GOTO390
380 GOSUB870
390 PRINTCHR$(147):PRINT:PRINT
400 PRINT"[212]HANKS FOR TAKING THIS TEST!":PRINT
410 PRINT"[211]OURCE: [202]. OF [208]SYCHOSOMATIC [210]ESEARCH"
420 PRINT"        [214]OL. 11, [208][208]. 213-218"
430 PRINT"        [196]R. [212]HOMAS [200]OLMES"
440 FORDL=1TO4000:NEXTDL
445 PRINT"[147]LOAD"CHR$(34)"PAYLOAD"CHR$(34)",8":PRINT"RUN"
450 POKE631,13:POKE632,13:POKE198,2
455 END
460 REM QUESTIONS
470 :
480 GOSUB180
490 PRINTCHR$(149);:PRINTTAB(14)"[198][193][195][212][207][210] # ";I;:PRINTCHR$(151)
500 L=LEN(T$(I))
510 L1$="":L2$=""
520 JJ=0
530 FORJ=1TOL
540 IFMID$(T$(I),J,1)="*"THENJJ=1:GOTO570
550 IFJJ=0THENL1$=L1$+MID$(T$(I),J,1)
560 IFJJ=1THENL2$=L2$+MID$(T$(I),J,1)
570 NEXTJ
580 K1=LEN(L1$)
590 K2=LEN(L1$)
600 K=K1:IFK2>K1THENK=K2
610 A=INT(40-K)/2
620 PRINTTAB(A)"";L1$
630 PRINTTAB(A)"";L2$
640 PRINTTAB(2)"[200]AVE YOU EXPERIENCED THIS IN THE LAST"
650 PRINTTAB(2)"12 MONTHS[160](Y/N)? ";
660 PRINTTAB(10):POKE204,0:POKE207,0:GETA$:POKE204,1
670 IFA$=""THEN 660
680 IFA$="N"THEN710
690 IFA$="Y"THENS=S+T(I):GOTO710
700 IFA$<>"N"ORA$<>"Y"THENPRINT:ZZ=18:ZY=12:GOSUB980:GOTO640
710 RETURN
720 :
730 REM HEALTH PROBLEM
740 :
750 PRINT"[193]CCORDING TO [196]RS. [212]HOMAS [200]OLMES AND"
760 PRINT:PRINT"[205]INORU [205]ASUDU, ANYONE SCORING 300 OR"
770 PRINT:PRINT"MORE IS VERY SUSCEPTIBLE TO MAJOR"
780 PRINT:PRINT"ILLNESS.  [195]ONSULT YOUR PHYSICIAN FOR"
790 PRINT:PRINT"MORE INFORMATION."
800 PRINTTAB(6)"[208]RESS SPACE BAR TO CONTINUE";
810 PRINTTAB(35):POKE204,0:POKE207,0:GETA$:IFA$=""THEN810
820 POKE204,1
830 RETURN
840 :
850 REM NO HEALTH PROBLEM
860 :
870 PRINT"[211]TRESS DUE TO SOCIAL CHANGES DOES NOT"
880 PRINT:PRINT"APPEAR TO BE A MAJOR HEALTH RISK FOR"
890 PRINT:PRINT"YOU.  [199][160][210][160][197][160][193][160][212]!"
900 PRINT:PRINT:PRINT"(300 OR MORE INDICATES RISK)"
910 PRINTTAB(6)"[208]RESS SPACE BAR TO CONTINUE";
920 PRINTTAB(35):POKE204,0:POKE207,0:GETA$:IFA$=""THEN920
930 POKE204,1
940 RETURN
950 :
960 REM ERROR MESSAGE
970 :
980 FORXZ=1TO20-ZZ:PRINT"";:NEXTXZ
990 PRINT"[211]ORRY.  [217]OU MADE AN INCORRECT ENTRY.    [208]LEASE RE-ENTER."
1000 FORXZ=1TO23-ZY:PRINT"[145]";:NEXTXZ
1010 RETURN
1020 :
1030 REM TITLE PAGE
1040 :
1050 PRINTCHR$(147):REM CLEAR/HOME SCREEN
1060 PRINTCHR$(144):PRINTTAB(14):PRINT"[211][212][210][197][211][211][160][212][197][211][212]":PRINTCHR$(149)
1070 PRINTTAB(18)"BY"
1080 PRINTTAB(13)"[202]OHN [194]ELTRAMI"
1090 PRINT TAB(6)"[212]RANSLATED BY [196]ONNA [203]. [215]OODY"
1100 PRINTTAB(7)"[208]RESS A KEY TO CONTINUE";
1110 PRINTTAB(35):POKE204,0:POKE207,0:GETA$
1120 IFA$=""THEN 1110
1130 POKE204,1:RETURN
1140 :
1150 REM INSTRUCTIONS
1160 :
1170 PRINT"   [195]HANGE, GOOD OR BAD, CAN PRODUCE":PRINT
1180 PRINT"STRESS.  [211]UFFICIENT STRESS CAN LEAD TO":PRINT
1190 PRINT"ILLNESS.  [212]HIS TEST WILL MEASURE SOME":PRINT
1200 PRINT"OF THE MAJOR SOURCES OF CHANGE IN YOUR":PRINT
1210 PRINT"LIFE.":PRINTTAB(7)"[208]RESS SPACE BAR TO CONTINUE";
1220 PRINTTAB(35):POKE204,0:POKE207,0:GETA$
1230 IFA$=""THEN 1220
1240 POKE204,1:RETURN
1250 :
1260 REM QUESTIONS AND SCORES IN THE FORM OF DATA STATEMENTS
1270 :
1280 DATA"[196]EATH OF SPOUSE",100
1290 DATA"[196]IVORCE",73
1300 DATA"[205]ARTIAL SEPARATION FROM MATE",65
1310 DATA"[196]ETENTION IN JAIL OR INSTITUTION",63
1320 DATA"[196]EATH OF CLOSE FAMILY MEMBER",63
1330 DATA"[205]AJOR PERSONAL INJURY OR ILLNESS",53
1340 DATA"[205]ARRIAGE",50
1350 DATA"[194]EING FIRED FROM WORK",47
1360 DATA"[205]ARITAL RECONCILATION WITH MATE",45
1370 DATA"[210]ETIREMENT FROM WORK",45
1380 DATA"[205]AJOR CHANGE IN HEALTH OF FAMILY MEM.",44
1390 DATA"[208]REGNACY",40
1400 DATA"[211]EXUAL DIFFICULTY",39
1410 DATA"[193]DDITIONAL HOUSEHOLD MEMBER",39
1420 DATA"[205]AJOR BUSINESS READJUSTMENT*(MERGER, BANKRUPTCY, ETC.)",39
1430 DATA"[205]AJOR CHANGE IN FINANCIAL STATE",38
1440 DATA"[196]EATH OF A CLOSE FRIEND",37
1450 DATA"[195]HANGING LINE OF WORK",36
1460 DATA"[205]AJOR CHANGE IN NUMBER OF ARGUMENTS*WITH SPOUSE (MORE OR LESS)",35
1470 DATA"[212]AKING OUT A MORTGAGE OR LOAN*FOR A MOJOR PURCHASE",31
1480 DATA"[198]ORECLOSURE ON MORTGAGE OR LOAN",30
1490 DATA"[205]AJOR CHANGE IN RESPONSIBILITIES*AT WORK (PROMOTION, DEMOTION, ETC.)"
1500 DATA29
1510 DATA"[211]ON OR DAUGHTER LEAVING HOME",29
1520 DATA"[201]N-LAW TROUBLES",29
1530 DATA"[207]UTSTANDING PERSONAL ACHIEVEMENT",28
1540 DATA"[215]IFE BEGINNING OR CEASING WORK*OUTSIDE THE HOME",26
1550 DATA"[194]EGINNING OR CEASING FORMAL SCHOOLING",26
1560 DATA"[205]AJOR CHANGE IN LIVING CONDITIONS",25
1570 DATA"[210]EVISION OF PERSONAL HABITS",24
1580 DATA"[212]ROUBLES WITH THE BOSS",23
1590 DATA"[205]AJOR CHANGE IN WORK HOURS",20
1600 DATA"[195]HANGE IN RESIDENCE",20
1610 DATA"[195]HANGING TO A NEW SCHOOL",20
1620 DATA"[205]AJOR CHANGE IN RECREATION HABITS",19
1630 DATA"[205]AJOR CHANGE IN CHURCH ACTIVITIES",19
1640 DATA"[205]AJOR CHANGE IN SOCIAL ACTIVITIES",18
1650 DATA"[212]AKING OUT A LOAN FOR A LESSER*PURCHASE (CAR, [212][214], ETC.)",17
1660 DATA"[205]AJOR CHANGE IN SLEEP HABITS",16
1670 DATA"[205]AJOR CHANGE IN NUMBER OF FAMILY*GET-TOGETHERS",15
1680 DATA"[205]AJOR CHANGE IN EATING HABITS",15
1690 DATA"[200]AD A VACATION",13
1700 DATA"[205]INOR VIOLATIONS OF THE LAW",11